À l’intérieur d’une chaîne "…" (description, aperçu, argument de dire, …), vous pouvez insérer des balises entre crochets droits […]. Le moteur les remplace par la valeur correspondante au moment de l’affichage.

Cette page liste les balises disponibles. Pour les conditions ([si …]), les blocs aléatoires ([au hasard]) et les variations selon l’occurrence ([1ère fois]), voir Conditions et blocs textuels. Pour les verbes conjugués ([v être ipr ceci]), voir Verbes conjugués.

Affiche le nom de X précédé de son article défini (le, la, l’, les).

dire "Vous voyez [intitulé ceci].".
-- → "Vous voyez la pomme rouge."
 
dire "[Intitulé ceci] brille faiblement.".
-- → "La pomme rouge brille faiblement." (majuscule forcée)

Pronom il / elle / ils / elles selon le genre et le nombre de X.

dire "[Pronom ceci] [v être ipr ceci] solide.".
-- → "Il est solide." ou "Elles sont solides."

Pronom complément le / la / l’ / les.

dire "Je ne [le ceci] vois pas actuellement.".
-- → "Je ne le vois pas actuellement."
 
dire "Je [l’ ceci]ai bu[es ceci].".
-- → "Je l’ai bue." (féminin singulier)
-- → "Je les ai bues." (féminin pluriel)

[l’ X] force l’élision (l’ ou les). [le X] choisit la forme appropriée (le / la / l’ / les).

Ajoute un s si X est au pluriel.

dire "Vous prenez [intitulé ceci]. [Pronom ceci] [v être ipr ceci] léger[s ceci].".
-- → "Vous prenez le caillou. Il est léger."
-- → "Vous prenez les cailloux. Ils sont légers."

Ajoute e / s / es selon le genre et le nombre de X.

dire "[Intitulé ceci] [v être ipr ceci] verrouillé[es ceci].".
-- → "Le coffre est verrouillé." (masc. sing. : rien)
-- → "La porte est verrouillée." (fém. sing. : "e")
-- → "Les coffres sont verrouillés." (masc. plur. : "s")
-- → "Les portes sont verrouillées." (fém. plur. : "es")

Ajoute uniquement le e du féminin (sans s pour le pluriel).

dire "Vous êtes prêt[accord le joueur] !".
-- → "Vous êtes prêt !" (joueur masculin)
-- → "Vous êtes prête !" (joueur féminin)

wiki_texte_accord_intitule

L'atelier est un lieu.
La porte est une porte ici.
Le coffre est un contenant ici.
Les fioles sont des objets ici.
 
action examiner ceci:
  dire "[Intitulé ceci] [v être ipr ceci] verrouillé[es ceci].".
fin action
 
règle avant commencer le jeu:
  dire "Essayez : {/examiner la porte/}, {/examiner le coffre/}, {/examiner les fioles/}.".
fin règle

tester cet exemple

Les mentions marquent un objet comme connu ou mentionné pendant l’affichage, et empêchent qu’il soit listé une seconde fois dans la description automatique du lieu. Particulièrement utile quand vous citez un objet dans la description d’un autre objet ou d’un lieu.

wiki_texte_mention_decor

La cuisine est un lieu.
Sa description est "Une cuisine simple. [@coffre] trône près de l'évier.".
 
Le coffre est un contenant dans la cuisine.
 
règle avant commencer le jeu:
  dire "Essayez : {/regarder/} — le coffre apparaît dans la description, pas dans la liste des objets en bas.".
fin règle

tester cet exemple

[description ceci]   -- description complète de l'objet
[aperçu ceci]        -- aperçu (texte court dans la liste des objets)
[texte ceci]         -- contenu textuel (lu via "lire")
[titre ici]          -- titre du lieu courant
[statut ceci]        -- "ouvert/fermé" pour une porte ou un contenant

Affiche la liste des directions accessibles depuis le lieu actuel.

dire "Vous voyez : [sorties ici].".
-- → "Vous voyez : au nord, à l’ouest et en bas."

Description de l’obstacle situé dans la direction X depuis le lieu courant.

Voir Propriétés personnalisées pour la déclaration. Pour l’affichage dans un texte :

dire "[Intitulé ceci] coûte [prix ceci] pièce[s prix ceci] d’or.".
dire "Le [matière ceci] vous va à ravir !".

Si [prop X] entre en conflit avec un autre mot-clé, ajoutez le préfixe p : [p prop X].

dire "[décrire objets dans le coffre]".
-- → "Dedans, il y a une clé, une bourse et une lettre."

dire "Score : [c score] point[s score].".
-- → "Score : 1 point." (singulier)
-- → "Score : 12 points." (pluriel)

Affichent les éléments d’une liste sous différentes formes.

Un mini-scénario où la description du grimoire change selon que le joueur porte la paire de lunettes, selon que la bougie est allumée, et selon la première lecture. Démontre aussi le verbe conjugué et l’accord.

ex_balises_grimoire

-- "Informations sur le jeu".
Le titre du jeu est "Le grimoire dynamique".
L’auteur du jeu est "DonjonFI".
 
Le bureau du bibliothécaire est un lieu.
Sa description est "Une vaste bibliothèque silencieuse. Sur le bureau central, [@grimoire ancien] repose près [si la bougie est allumée]d’une bougie allumée dont la flamme vacille[sinon]d’une bougie éteinte[fin si].".
 
Le bureau central est un support dans le bureau du bibliothécaire.
 
Le grimoire ancien est un objet décoratif sur le bureau central.
Sa description est "Un grand grimoire à la couverture de cuir râpé.{n}[si le joueur possède la paire de lunettes]Avec [intitulé la paire de lunettes], vous lisez : << Le secret se trouve sous [#bougie]. >>[sinon]Sans lunettes, les caractères restent illisibles.[fin si]{n}[1ère fois]({/Une odeur d’encre ancienne flotte dans l’air./})[fin]".
 
La bougie est un objet allumé sur le bureau central.
Sa description est "Une bougie de cire jaune. [Pronom ceci] [v être ipr ceci] [si la bougie est allumée]allumée[sinon]éteinte[fin si].".
 
La paire de lunettes est un objet portable sur le bureau central.
 
Le bibliothécaire est une personne décorative dans le bureau du bibliothécaire.
Sa description est "Un homme âgé. [Pronom ceci] [v être ipr ceci] vêtu[es ceci] d’une longue robe grise.".
 
Le joueur est dans le bureau du bibliothécaire.

tester cet exemple

• Verbes conjugués — [v verbe mode-temps X]
• Conditions et blocs textuels — [si …], [1ère fois], [au hasard]
• Mise en forme — gras, italique, couleurs, espaces
• Instruction « dire »
• Propriétés personnalisées