Une règle après s’exécute après qu’une action ait eu lieu. Par défaut, la phase « épilogue » de l’action n’est pas exécutée — la règle remplace le texte de sortie habituel pour vous permettre d’écrire le vôtre.

Voir Règles (avant / après) pour les concepts généraux et la syntaxe des déclencheurs.

règle après jeter la bille vers la lucarne:
  dire "[au hasard]Vous atteignez la lucarne, ça fait << poc >> puis la bille retombe.[ou]Raté.[ou]Bien essayé.[fin choix]".
fin règle
 
règle après donner l’anneau au roi, donner l’anneau au prince ou donner l’anneau à la reine:
  dire "<< Grâce à vous le royaume est sauvé ! >>".
fin règle
 
règle après parler à un chien:
  dire "<< Wouf ! >>".
fin règle

wiki_regles_apres_donner

La salle du trône est un lieu.
Le roi est un homme ici.
La reine est une femme ici.
L'anneau est un objet dans l'inventaire.
 
règle après donner l'anneau au roi ou donner l'anneau à la reine:
  dire "« Grâce à vous le royaume est sauvé ! »".
fin règle
 
règle avant commencer le jeu:
  dire "Essayez : {/donner l'anneau au roi/} ou {/donner l'anneau à la reine/}.".
fin règle

tester cet exemple

règle après prendre la pomme:
  si la règle se déclenche pour la première fois:
    dire "Vous saisissez la pomme royalement.".
  sinonsi la règle se déclenche pour la deuxième fois:
    dire "Encore une pomme...".
  sinon
    continuer l’action.
  fin si
fin règle
 
règle après sauter:
  si la règle ne se déclenche pas pour la première fois:
    dire "Vous avez fini de sauter ?".
  fin si
fin règle

Par défaut, la règle remplace la sortie standard. Deux instructions permettent de réintroduire la sortie standard, selon l’ordre voulu :

-- La description du nouveau lieu s’affiche AVANT le murmure
règle après aller dans la crypte:
  continuer l’action avant.
  dire "Une voix murmure : << Sans le feu, tu ne survivras pas ici… >>".
fin règle
 
-- La cinématique s’affiche AVANT la description du nouveau lieu
règle après aller dans la crypte:
  dire "Vous descendez prudemment dans l’obscurité.".
  continuer l’action après.
fin règle

Sans aucune de ces deux instructions, la sortie standard est totalement remplacée par celle de la règle — utile pour les cinématiques qui se substituent à la description automatique.

wiki_regles_continuer_action

La cour est un lieu.
La crypte est un lieu sous la cour.
Sa description est "Une crypte glaciale. L'obscurité y est totale.".
 
règle après aller dans la crypte:
  dire "Vous descendez prudemment dans l'obscurité.".
  continuer l'action après.
fin règle
 
règle avant commencer le jeu:
  dire "Essayez : {/aller en bas/} (la cinématique précède la description du nouveau lieu).".
fin règle

tester cet exemple

Le journal intime : démontre une règle avant qui refuse de prendre l’objet, une règle après qui ajoute une cinématique uniquement à la première lecture (avec continuer l’action après), et une règle à déclencheurs combinés.

ex_regles_journal

-- "Informations sur le jeu".
Le titre du jeu est "Le journal intime".
L’auteur du jeu est "DonjonFI".
 
La chambre est un lieu.
Sa description est "Votre chambre. Une table de nuit, un miroir au mur, et — fermée à clé — la porte du couloir.".
 
La table de nuit est un support dans la chambre.
 
Le journal intime est un objet décoratif sur la table de nuit.
Sa description est "Un carnet relié de cuir noir. Les pages sont remplies d’une écriture serrée.".
 
Le miroir est un objet décoratif fixé dans la chambre.
Sa description est "Vous y voyez votre reflet, l’air songeur.".
 
La photo de famille est un objet décoratif sur la table de nuit.
Sa description est "Une photo un peu jaunie. Vos parents y sourient.".
 
-- Initialisation
règle avant commencer le jeu:
  dire "Vous êtes seul dans votre chambre.{p}".
fin règle
 
-- Règle avant : refuser une action existante (prendre).
règle avant prendre le journal intime:
  dire "C’est bien trop intime pour le laisser traîner ailleurs.".
  refuser l’action.
fin règle
 
-- Règle après : cinématique uniquement à la 1ère lecture, puis description standard.
règle après examiner le journal intime:
  si la règle se déclenche pour la première fois:
    dire "Vous prenez le journal et hésitez avant de l’ouvrir.{p}".
    continuer l’action après.
  sinon
    continuer l’action.
  fin si
fin règle
 
-- Déclencheurs combinés (« ou »).
règle après examiner le miroir ou examiner la photo de famille:
  dire "({/Un souvenir vous traverse l’esprit./})".
fin règle
 
Le joueur est dans la chambre.

tester cet exemple

À tester :

• examiner le journal deux fois — la 1ère a la cinématique, la 2ème non
• prendre le journal → refusé
• examiner le miroir puis examiner la photo → le même texte additionnel

• Règles (avant / après) — index
• Règle avant
• Instruction « continuer »
• Actions personnalisées — pour créer un nouveau verbe (à distinguer)