-- ============
--   REGARDER
-- ============
 
-- a) regarder
regarder est une action.
 
terminer regarder:
  dire "{_{*[titre ici]*}_}";
  dire "{n}[description ici][décrire objets ici]";
  dire "{n}{n}[sorties ici]".
 
-- b) regarder ceci
regarder ceci est une action qui concerne un élément.
 
refuser regarder ceci:
  si ceci n’est ni visible ni l’inventaire, dire "Je ne vois pas [intitulé ceci] actuellement.".
 
terminer regarder ceci:
-- objet
  si ceci est un objet:
-- >> description de l’objet
    dire "[description ceci] ";
-- >> statut de l’objet
    si ceci est une porte ou un contenant,
      dire "{N}[statut ceci]";
-- >> contenu de l’objet
    si ceci est un contenant et ouvert :
      dire "[décrire objets dans ceci]";
    sinonsi ceci est un contenant et fermé et transparent :
      dire "[décrire objets dans ceci]";
    sinonsi ceci est un support :
      dire "[décrire objets sur ceci]";
    fin si;
--  >> ojbet inaccessible
    si ceci n'est ni accessible ni l’inventaire, 
      dire " [Pronom ceci] n'est pas accessible.";
--  >> inventaire
    si ceci est l’inventaire,
      dire "Votre inventaire [si l’inventaire contient un objet]contient : [lister objets inventaire][sinon]est vide.[fin si]";
-- lieu
  sinonsi ceci est un lieu :
    dire "{_{*[titre ici]*}_}";
    dire "{n}[description ici][décrire objets ici]";
    dire "{n}{n}[sorties ici]";
-- inconnu
  sinon
    dire "Hum ceci n’est ni un objet ni un lieu. Je ne connais pas.";
  fin si.
 
 
L'aide pour l'action regarder est "{*Regarder*}
  Permet de regarder autours de vous pour en savoir plus sur le lieu où vous vous trouvez.
  {+exemple+} :
  > {-regarder-}
  {+raccourci+} : {-re-}".
 
interpréter observer comme regarder.