-- ============
--   EXAMINER
-- ============
 
-- a) examiner
le joueur peut examiner:
  dire "(Si vous souhaitez examiner quelque chose, il faut préciser quoi.)".
 
-- b) examiner ceci
examiner ceci est une action qui concerne un élément visible.
 
refuser examiner ceci:
  si ceci est une personne, dire "Pas sûr qu'[pronom ceci] ait envie de jouer au docteur.".
 
terminer examiner ceci:
  si ceci est le joueur:
    dire "Étrange...{n}";
  si ceci est un objet:
    dire "[description ceci] ";
  si ceci est une porte ou un contenant :
    dire "{n}[statut ceci]";
  si ceci est un contenant et ouvert:
    dire "[contenu ceci]";
  si ceci est un contenant et fermé et transparent:
    dire "[contenu ceci]";
  si ceci est un support:
    dire "[contenu ceci]";
  si ceci n'est ni accessible ni un lieu:
    dire " [Pronom ceci] n'est pas accessible.";
  si ceci n'est ni un contenant ni un support:
    dire "[si aucune description pour ceci]Vous ne trouvez rien d’intéressant.[fin si]";
  si ceci est un lieu:
    dire "Veuillez préciser quel élément vous souhaitez examiner.".
 
interpréter fouiller comme examiner.
 
L'aide pour l'action examiner est "{*Examiner*}
  Permet d'examiner un élément du jeu pour avoir des détails ou trouver un objet.
  {+exemples+} :
  > {-examiner {/l'arbre/}-}
  > {-examiner {/l'épée/}}
  {+raccourci+} : {-ex-}".