-- ============
--   EXAMINER
-- ============
 
-- a) examiner
le joueur peut examiner:
  dire "(Si vous souhaitez examiner quelque chose, il faut préciser quoi.)".
 
-- b) examiner ceci
examiner ceci est une action qui concerne un élément.
 
refuser examiner ceci:
  si ceci n’est ni visible ni l’inventaire, dire "Je ne vois pas [intitulé ceci] actuellement.";
  si ceci est une personne, dire "Pas sûr qu'[pronom ceci] [v avoir spr ceci] envie de jouer au docteur.".
 
terminer examiner ceci:
-- objet
  si ceci est un objet:
    si ceci est le joueur,
      dire "Étrange...{n}";
-- >> description de l’objet
    dire "[description ceci] ";
-- >> statut de l’objet
    si ceci est une porte ou un contenant,
      dire "{N}[statut ceci]";
-- >> contenu de l’objet
    si ceci est un contenant et ouvert :
      dire "[décrire objets dans ceci]";
    sinonsi ceci est un contenant et fermé et transparent :
      dire "[décrire objets dans ceci]";
    sinonsi ceci est un support :
      dire "[décrire objets sur ceci]";
    fin si;
--  >> ojbet inaccessible
    si ceci n'est ni accessible ni l’inventaire, 
      dire " [Pronom ceci] n'est pas accessible.";
--  >> inventaire
    si ceci est l’inventaire,
      dire "Votre inventaire [si l’inventaire contient un objet]contient : [lister objets inventaire][sinon]est vide.[fin si]";
-- lieu
  sinonsi ceci est un lieu :
    dire "{_{*[titre ici]*}_}";
    dire "{n}[description ici][décrire objets ici]";
    dire "{n}{n}[sorties ici]";
-- inconnu
  sinon
    dire "Hum ceci n’est ni un objet ni un lieu. Je ne connais pas.";
  fin si.
 
interpréter fouiller comme examiner.
 
L'aide pour l'action examiner est "{*Examiner*}
  Permet d'examiner un élément du jeu pour avoir des détails ou trouver un objet.
  {+exemples+} :
  > {-examiner {/l'arbre/}-}
  > {-examiner {/l'épée/}}
  {+raccourci+} : {-ex-}".